大俠夫人的家

線上說明：Adobe ActionScript 3.0-使用 ColorPicker組件

範例1：建立具有 ColorPicker 組件的應用程式

說明：

在此範例中，每一次變更 ColorPicker 中的顏色時，changeHandler() 函數都會呼叫 drawBox() 函數，繪製具有您在 ColorPicker 中選取之顏色的新方塊。

步驟：

1.建立新的 Flash (ActionScript 3.0) 文件。

2.將 ColorPicker 從「組件」面板拖曳到「舞台」，並賦予實體名稱 aCp。

3.開啟「動作」面板，選取主要「時間軸」中的「影格 1」，然後輸入下列 ActionScript 程式碼：

import fl.events.ColorPickerEvent;

var aBox:MovieClip = new MovieClip();

drawBox(aBox, 0xFF0000); //draw a red box

addChild(aBox);

aCp.addEventListener(ColorPickerEvent.CHANGE,changeHandler);

function changeHandler(event:ColorPickerEvent):void {

   drawBox(aBox, event.target.selectedColor);

}

function drawBox(box:MovieClip,color:uint):void {

     box.graphics.beginFill(color, 1);

     box.graphics.drawRect(70, 50, 100, 100);

     box.graphics.endFill();

}

4.選取「控制 > 測試影片」。

5.按一下 ColorPicker 並選取顏色，為方塊上色。

範例2：使用 ActionScript 建立 TextArea 實體

說明：

此範例會使用 ColorPicker() 建構函式和 addChild()，在「舞台」上建立 ColorPicker。接著將 colors 屬性設定為紅色、橘色、綠色與藍色的顏色值，以指定 ColorPicker 將要顯示的顏色。另外還會建立 TextArea。每當您從 ColorPicker 選取不同的顏色時，TextArea 中的文字顏色隨即變更為相符的顏色。

步驟：

1.建立新的 Flash (ActionScript 3.0) 文件。

2.將 ColorPicker 組件從「組件」面板拖曳到「元件庫」面板。

3.將 TextArea 組件從「組件」面板拖曳到「元件庫」面板。

4.開啟「動作」面板，選取主要「時間軸」中的「影格 1」，然後輸入下列 ActionScript 程式碼：

import fl.controls.ColorPicker;

import fl.controls.TextArea;

import fl.events.ColorPickerEvent;

var aCp:ColorPicker = new ColorPicker();

var aTa:TextArea = new TextArea();

var aTf:TextFormat = new TextFormat();

aCp.move(10, 10);

aCp.colors = [0xff0000, 0xf5881c,0x007f00, 0x0000ff];

aCp.addEventListener(ColorPickerEvent.CHANGE, changeHandler);

aTa.htmlText = "<font size='16'>床前看月光，<br>疑是地上霜。<br>舉頭望明月，<br>低頭思故鄉。</font>";

aTa.setSize(200, 100);

aTa.move(110,10);

addChild(aCp);

addChild(aTa);

function changeHandler(event:ColorPickerEvent):void {

    if(TextFormat(aTa.getStyle("textFormat"))){

        aTf = TextFormat(aTa.getStyle("textFormat"));

    }

    aTf.color = event.target.selectedColor;

    aTa.setStyle("textFormat", aTf);

}

此範例利用 htmlText 屬性，使文字區塊套用 HTML 指定字體大小與換行特質，並將文字區塊顯示在 a_ta 文字區域中。setSize() 方法設定了文字區域的高度與寬度，而 move() 方法則設定其位置。addChild() 方法會將 TextArea 實體加入至「舞台」。

5.選取「控制 > 測試影片」。